Type Object

The Type Object pattern is a design pattern that helps you create objects that can be plugged into another and change its type or behavior. The idea is to take data that could be part of a class (like a character's stats for example) and move it into a separate object that you can plug into that class.

This simple pattern is very helpful in games because it lets you create and modify content quickly. With it, game designers can define new entity types without asking a programmer to write new code. They just create a new type object with different properties.

You'll often use this pattern for character stats, character jobs or classes, and for pickup items. It's also used a lot in Godot, with its built-in resource system: you can easily plug a material, a shader, a mesh into different containers to change how they look. That's the type object pattern in action!

Coding your own Type Objects

In Godot, you can use resources yourself to create type objects that can even be saved to the disk. For example:

class_name Job extends Resource

@export var job_name := ""
@export var max_health := 10
@export var attack_damage := 5
@export var defense := 2
@export var abilities: Array[Ability] = []

Then you create a resource file for each job type in the Godot editor or in code. In this example, I defined the warrior job using code:

func create_warrior_type() -> Job:
	var warrior_type = Job.new()
	warrior_type.job_name = "Warrior"
	warrior_type.max_health = 100
	warrior_type.attack_damage = 15
	warrior_type.defense = 8
	return warrior_type

Here's an example of how you would use the job type in a character script:

class_name Character extends CharacterBody2D

@export var job: Job = null
@export var movement_speed := 100.0

var current_health := 0


func _ready() -> void:
	if job != null:
		current_health = job.max_health
		movement_speed = job.movement_speed


func _physics_process(delta: float) -> void:
	var direction := Input.get_vector("move_left", "move_right", "move_up", "move_down")
	velocity = direction * movement_speed
	move_and_slide()